atmel-samd: Turn on SAMD51 bootloader build layout. (#348)

3 files changed, 83 insertions, 2 deletions

diff --git a/atmel-samd/boards/metro_m4_express/mpconfigboard.mk b/atmel-samd/boards/metro_m4_express/mpconfigboard.mk
index a21be5138..8dfb07c50 100644
--- a/atmel-samd/boards/metro_m4_express/mpconfigboard.mk
+++ b/atmel-samd/boards/metro_m4_express/mpconfigboard.mk
@@ -1,4 +1,4 @@
-LD_FILE = boards/samd51x20.ld
+LD_FILE = boards/samd51x20-bootloader.ld
 USB_VID = 0x239A
 USB_PID = 0x8015
 
diff --git a/atmel-samd/boards/samd51x20-bootloader.ld b/atmel-samd/boards/samd51x20-bootloader.ld
new file mode 100644
index 000000000..3d6621a5a
--- /dev/null
+++ b/atmel-samd/boards/samd51x20-bootloader.ld
@@ -0,0 +1,81 @@
+/*
+    GNU linker script for SAMD51
+*/
+
+/* Specify the memory areas */
+MEMORY
+{
+    FLASH (rx) : ORIGIN = 0x00000000 + 0x4000, LENGTH = 0x00100000 - 0x4000  - 0x80000 /* Leave 16KiB for the bootloader and 512k for the filesystem. */
+    RAM (xrw)       : ORIGIN = 0x20000000, LENGTH = 0x00040000 /* 256 KiB */
+}
+
+/* top end of the stack */
+_estack = ORIGIN(RAM) + LENGTH(RAM);
+
+/* define output sections */
+SECTIONS
+{
+    /* The program code and other data goes into FLASH */
+    .text :
+    {
+        . = ALIGN(4);
+        _sfixed = .;
+        KEEP(*(.vectors)) /* isr vector table */
+        *(.text)           /* .text sections (code) */
+        *(.text*)          /* .text* sections (code) */
+        *(.rodata)         /* .rodata sections (constants, strings, etc.) */
+        *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
+
+        . = ALIGN(4);
+        _etext = .;        /* define a global symbol at end of code */
+    } >FLASH
+
+    .ARM.exidx :
+    {
+        *(.ARM.exidx*)
+        *(.gnu.linkonce.armexidx.*)
+        _sidata = .;  /* This is used by the startup in order to initialize the .data section */
+    } > FLASH
+
+    /* This is the initialized data section
+    The program executes knowing that the data is in the RAM
+    but the loader puts the initial values in the FLASH (inidata).
+    It is one task of the startup to copy the initial values from FLASH to RAM. */
+    .data : AT ( _sidata )
+    {
+        . = ALIGN(4);
+        _srelocate = .;        /* create a global symbol at data start; used by startup code in order to initialise the .data section in RAM */
+        *(.ramfunc)
+        *(.ramfunc*)
+        *(.data)           /* .data sections */
+        *(.data*)          /* .data* sections */
+
+        . = ALIGN(4);
+        _erelocate = .;        /* define a global symbol at data end; used by startup code in order to initialise the .data section in RAM */
+    } >RAM
+
+    /* Uninitialized data section */
+    .bss :
+    {
+        . = ALIGN(4);
+        _sbss = .;
+        _szero = .;         /* define a global symbol at bss start; used by startup code */
+        *(.bss)
+        *(.bss*)
+        *(COMMON)
+
+        . = ALIGN(4);
+        _ezero = .;         /* define a global symbol at bss end; used by startup code */
+        _ebss = .;
+    } >RAM
+
+    /* this just checks there is enough RAM for a minimal stack */
+    .stack :
+    {
+        . = ALIGN(4);
+        . = . + 0x800; /* Reserve a minimum of 2K for the stack. */
+        . = ALIGN(4);
+    } >RAM
+
+    .ARM.attributes 0 : { *(.ARM.attributes) }
+}
diff --git a/atmel-samd/boards/samd51x20.ld b/atmel-samd/boards/samd51x20.ld
index 4d2da5d13..ed26425f3 100644
--- a/atmel-samd/boards/samd51x20.ld
+++ b/atmel-samd/boards/samd51x20.ld
@@ -5,7 +5,7 @@
 /* Specify the memory areas */
 MEMORY
 {
-    FLASH (rx) : ORIGIN = 0x00000000, LENGTH = 0x00100000 - 0x80000 /* 1024 KiB mius 512KiB for the internal file system. */
+    FLASH (rx) : ORIGIN = 0x00000000, LENGTH = 0x00100000 - 0x80000 /* 1024 KiB minus 512KiB for the internal file system. */
     RAM (xrw)       : ORIGIN = 0x20000000, LENGTH = 0x00040000 /* 256 KiB */
 }