stmhal: Make ld and af files configurable within Makefile.

Each board now needs an mpconfigboard.mk file which defines AF_FILE and
LD_FILE.

Also moved stm32f405.ld to boards/ directory to keep things organised.

8 files changed, 150 insertions, 0 deletions

diff --git a/stmhal/boards/CERB40/mpconfigboard.mk b/stmhal/boards/CERB40/mpconfigboard.mk
new file mode 100644
index 000000000..3c2bdab98
--- /dev/null
+++ b/stmhal/boards/CERB40/mpconfigboard.mk
@@ -0,0 +1,2 @@
+AF_FILE = boards/stm32f405_af.csv
+LD_FILE = boards/stm32f405.ld
diff --git a/stmhal/boards/HYDRABUS/mpconfigboard.mk b/stmhal/boards/HYDRABUS/mpconfigboard.mk
new file mode 100644
index 000000000..3c2bdab98
--- /dev/null
+++ b/stmhal/boards/HYDRABUS/mpconfigboard.mk
@@ -0,0 +1,2 @@
+AF_FILE = boards/stm32f405_af.csv
+LD_FILE = boards/stm32f405.ld
diff --git a/stmhal/boards/NETDUINO_PLUS_2/mpconfigboard.mk b/stmhal/boards/NETDUINO_PLUS_2/mpconfigboard.mk
new file mode 100644
index 000000000..3c2bdab98
--- /dev/null
+++ b/stmhal/boards/NETDUINO_PLUS_2/mpconfigboard.mk
@@ -0,0 +1,2 @@
+AF_FILE = boards/stm32f405_af.csv
+LD_FILE = boards/stm32f405.ld
diff --git a/stmhal/boards/PYBV10/mpconfigboard.mk b/stmhal/boards/PYBV10/mpconfigboard.mk
new file mode 100644
index 000000000..3c2bdab98
--- /dev/null
+++ b/stmhal/boards/PYBV10/mpconfigboard.mk
@@ -0,0 +1,2 @@
+AF_FILE = boards/stm32f405_af.csv
+LD_FILE = boards/stm32f405.ld
diff --git a/stmhal/boards/PYBV3/mpconfigboard.mk b/stmhal/boards/PYBV3/mpconfigboard.mk
new file mode 100644
index 000000000..3c2bdab98
--- /dev/null
+++ b/stmhal/boards/PYBV3/mpconfigboard.mk
@@ -0,0 +1,2 @@
+AF_FILE = boards/stm32f405_af.csv
+LD_FILE = boards/stm32f405.ld
diff --git a/stmhal/boards/PYBV4/mpconfigboard.mk b/stmhal/boards/PYBV4/mpconfigboard.mk
new file mode 100644
index 000000000..3c2bdab98
--- /dev/null
+++ b/stmhal/boards/PYBV4/mpconfigboard.mk
@@ -0,0 +1,2 @@
+AF_FILE = boards/stm32f405_af.csv
+LD_FILE = boards/stm32f405.ld
diff --git a/stmhal/boards/STM32F4DISC/mpconfigboard.mk b/stmhal/boards/STM32F4DISC/mpconfigboard.mk
new file mode 100644
index 000000000..3c2bdab98
--- /dev/null
+++ b/stmhal/boards/STM32F4DISC/mpconfigboard.mk
@@ -0,0 +1,2 @@
+AF_FILE = boards/stm32f405_af.csv
+LD_FILE = boards/stm32f405.ld
diff --git a/stmhal/boards/stm32f405.ld b/stmhal/boards/stm32f405.ld
new file mode 100644
index 000000000..5d9f0d2a9
--- /dev/null
+++ b/stmhal/boards/stm32f405.ld
@@ -0,0 +1,136 @@
+/*
+    GNU linker script for STM32F405
+*/
+
+/* Specify the memory areas */
+MEMORY
+{
+    FLASH (rx)      : ORIGIN = 0x08000000, LENGTH = 0x100000 /* entire flash, 1 MiB */
+    FLASH_ISR (rx)  : ORIGIN = 0x08000000, LENGTH = 0x004000 /* sector 0, 16 KiB */
+    FLASH_TEXT (rx) : ORIGIN = 0x08020000, LENGTH = 0x080000 /* sectors 5,6,7,8, 4*128KiB = 512 KiB (could increase it more) */
+    CCMRAM (xrw)    : ORIGIN = 0x10000000, LENGTH = 0x010000 /* 64 KiB */
+    RAM (xrw)       : ORIGIN = 0x20000000, LENGTH = 0x020000 /* 128 KiB */
+}
+
+ENTRY(Reset_Handler)
+
+/* produce a link error if there is not this amount of RAM for these sections */
+_minimum_stack_size = 2K;
+_minimum_heap_size = 16K;
+ 
+/* Define tho top end of the stack.  The stack is full descending so begins just
+   above last byte of RAM.  Note that EABI requires the stack to be 8-byte
+   aligned for a call. */
+_estack = ORIGIN(RAM) + LENGTH(RAM);
+
+/* RAM extents for the garbage collector */
+_ram_end = ORIGIN(RAM) + LENGTH(RAM);
+_heap_end = 0x2001c000; /* tunable */
+
+/* define output sections */
+SECTIONS
+{
+    /* The startup code goes first into FLASH */
+    .isr_vector :
+    {
+        . = ALIGN(4);
+        KEEP(*(.isr_vector)) /* Startup code */
+
+        /* This first flash block is 16K annd the isr vectors only take up
+           about 400 bytes. So we pull in a couple of object files to pad it
+           out. */
+
+        . = ALIGN(4);
+        */ff.o(.text*)
+        */stm32f4xx_hal_sd.o(.text*)
+
+        . = ALIGN(4);
+    } >FLASH_ISR
+   
+    /* The program code and other data goes into FLASH */
+    .text :
+    {
+        . = ALIGN(4);
+        *(.text*)          /* .text* sections (code) */
+        *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
+    /*  *(.glue_7)   */    /* glue arm to thumb code */
+    /*  *(.glue_7t)  */    /* glue thumb to arm code */
+
+        . = ALIGN(4);
+        _etext = .;        /* define a global symbol at end of code */
+    } >FLASH_TEXT
+     
+    /*
+    .ARM.extab :
+    {
+        *(.ARM.extab* .gnu.linkonce.armextab.*)
+    } >FLASH
+
+    .ARM :
+    {
+        __exidx_start = .;
+        *(.ARM.exidx*)
+        __exidx_end = .;
+    } >FLASH
+    */
+        
+    /* used by the startup to initialize data */
+    _sidata = LOADADDR(.data);
+        
+    /* This is the initialized data section
+    The program executes knowing that the data is in the RAM
+    but the loader puts the initial values in the FLASH (inidata).
+    It is one task of the startup to copy the initial values from FLASH to RAM. */
+    .data :
+    {
+        . = ALIGN(4);
+        _sdata = .;        /* create a global symbol at data start; used by startup code in order to initialise the .data section in RAM */
+        _ram_start = .;    /* create a global symbol at ram start for garbage collector */
+        *(.data*)          /* .data* sections */
+
+        . = ALIGN(4);
+        _edata = .;        /* define a global symbol at data end; used by startup code in order to initialise the .data section in RAM */
+    } >RAM AT> FLASH_TEXT
+            
+    /* Uninitialized data section */
+    .bss :
+    {
+        . = ALIGN(4);
+        _sbss = .;         /* define a global symbol at bss start; used by startup code */
+        *(.bss*)
+        *(COMMON)
+
+        . = ALIGN(4);
+        _ebss = .;         /* define a global symbol at bss end; used by startup code and GC */
+    } >RAM
+
+    /* this is to define the start of the heap, and make sure we have a minimum size */
+    .heap :
+    {
+        . = ALIGN(4);
+	PROVIDE ( end = . );
+	PROVIDE ( _end = . );
+        _heap_start = .;    /* define a global symbol at heap start */
+        . = . + _minimum_heap_size;
+    } >RAM
+
+    /* this just checks there is enough RAM for the stack */
+    .stack :
+    {
+        . = ALIGN(4);
+        . = . + _minimum_stack_size;
+        . = ALIGN(4);
+    } >RAM
+
+    /* Remove information from the standard libraries */
+    /*
+    /DISCARD/ :
+    {
+        libc.a ( * )
+        libm.a ( * )
+        libgcc.a ( * )
+    }
+    */
+
+    .ARM.attributes 0 : { *(.ARM.attributes) }
+}